10 REM MORSE.BAS  by Emmanuel ROCHE
20 :
30 REM  ! " # $ % & '
40 DATA -.-.--, .-..-., "#", ...-..-, "%", .-..., .----.
50 REM  ( ) * + , - . /
60 DATA -.--., -.--.-, "*", .-.-., "--..--", -....-, .-.-.-, -..-.
70 REM  0 1 2 3 4 5 6 7
80 DATA -----, .----, ..---, ...--, ....-, ....., -...., --...
90 REM  8 9 : ; < = > ?
100 DATA ---.., ----., ---..., -.-.-., "<", "-...-", ">", "..--.."
110 REM  @ A B C D E F G
120 DATA .--.-., .-, -..., -.-., -.., ., ..-., --.
130 REM  H I J K L M N O
140 DATA ...., .., .---, -.-, .-.., --, -., ---
150 REM  P Q R S T U V W
160 DATA .--., --.-, .-., ..., -, ..-, ...-, .--
170 REM  X Y Z [ \ ] ^ _
180 DATA -..-, -.--, --.., "[", "\", "]", "^", ..--.-
190 REM  ` a b c d e f g
200 DATA "`", .-, -..., -.-., -.., ., ..-., --.
210 REM  h i j k l m n o
220 DATA ...., .., .---, -.-, .-.., --, -., ---
230 REM  p q r s t u v w
240 DATA .--., --.-, .-., ..., -, ..-, ...-, .--
250 REM  x y z { | } ~
260 DATA -..-, -.--, --.., "{", "|", "}", "~"
270 :
280 DIM code$ (126)
290 FOR c = 33 TO 126
300     READ code$ (c)
310 NEXT c
320 PRINT
330 LINE INPUT "MORSE> ", msg$
340 PRINT
350 L = LEN (msg$)
360 FOR d = 1 TO L
370     PRINT code$(ASC(MID$(msg$,d,1)))" ";
380 '    PRINT MID$(msg$,d,1)" = "code$(ASC(MID$(msg$,d,1)))
390 NEXT d
400 PRINT
410 PRINT
420 GOTO 330